/* Create TP701 HPFS hibernate file */

say 'Enter size of system memory in megabytes: '
memsize = linein()
if ((datatype(memsize) <> 'NUM') | (memsize < 4) | ,
    (memsize > 64) | (memsize//4 <> 0)) then do
  say 'Size must be a number from 4 to 64 and a multiple of 4.'; return
end
say 'Enter HPFS drive letter: '
drive = linein()
if (length(drive) <> 1) then do
  say 'Drive letter must be a single character.'; return
end

/* Create some big blank variables */
oneMeg = substr(' ', 1, 1024*1024)
Six4K  = substr(' ', 1, 1024*64)

/* Delete hibernate file if it exists */
'@attrib -r -s -h "'drive':\TP 701.HIB" >nul 2>nul'
'@del "'drive':\TP 701.HIB" >nul 2>nul'

msg = stream(drive":\TP 701.HIB", 'C', 'OPEN WRITE')
if (msg = "READY:") then do
  /* Write data in 1M blocks */
  do memsize
    call charout drive":\TP 701.HIB", oneMeg
  end
  /* Add 1M for video */
  call charout drive":\TP 701.HIB", oneMeg
  /* Add 64K */
  call charout drive":\TP 701.HIB", Six4K

  msg = stream(drive":\TP 701.HIB", 'C', 'CLOSE')
'@attrib +h "'drive':\TP 701.HIB" >nul 2>nul'
  say 'Done, 'memsize+1' megabytes (+64K) written.'
end
else say 'Error opening HIB file: 'msg

return